; ************************************************************
;       Programme: lab_d_8.txt     version PEP813 sous Windows
;
;       INF2171 - laboratoire sur DECI
;       8) Modifier le nouveau programme PREMIERx (étape 3) afin de déterminer le plus petit et le plus grand nombre lu.
;
;       auteur:         Bernard Martin
;       code permanent: non applicable
;       courriel:       martin.bernard@uqam.ca
;       date:           hiver 2019
;       cours:          INF2171
; ***********************************************************
;
début:   LDA     32767,i     ; valeur possible la plus haute
         STA     petit,d     
         LDA     -32767,i    ; valeur possible la plus basse (-32768 est une exception)
         STA     grand,d     
;
         DECI    nombre,d    ; lecture d'un nombre
         BREQ    FINI        ; si le nombre lu est zéro, on termine définitivement le programme
boucle:  NOP0                
         LDX     nombre,d    
         CPX     -32768,i    ; le nombre -32768 est rejeté
         BRNE    accepté     
         STRO    msgrejet,d  ; et doit »etre relu
         BR      lecture     
;
accepté: CPX     petit,d     ; le plus petit ?
         BRGT    nonpetit    
         STX     petit,d     
;
nonpetit:CPX     grand,d     ; le plus grand ?
         BRLT    nongrand    
         STX     grand,d     
nongrand:NOP0                
lecture: DECI    nombre,d    ; lecture d'un autre nombre
         BRNE    boucle      ; zéro termine la sommation
;
termine: CHARO   "\n",i      ; nouvelle ligne
         DECO    petit,d     ; affiche le plus petit nombre lu
         CHARO   " ",i       ; séparateur
         DECO    grand,d     ; affiche le plus grand nombre lu
         CHARO   "\n",i      ; nouvelle ligne
         CHARO   "\n",i      ; nouvelle ligne
         BR      début       
;
FINI:    STOP                
;
msgrejet:.ASCII  "La donnée doit se trouver entre -32767 et +32767."
         .ASCII  "\nVeuillez l'entrer de nouveau: \x00"
nombre:  .BLOCK  2           ; #2d valeur initiale zéro
total:   .BLOCK  2           ; #2d valeur initiale zéro
petit:   .BLOCK  2           ; #2d
grand:   .BLOCK  2           ; #2d
;
         .END