; ***********************************************************************
; Programme: SXF-1.TXT          version PEP813 sous WINDOWS
;
;       Ce programme fait appel à une routine qui affiche le Xième
;       caractère de l'alphabet.
;       Ce caractère sera choisi par l'utilisateur.
;
;       auteur:         Bernard Martin
;       code permanent: non applicable
;       courriel:       martin.bernard@uqam.ca
;       date:           hiver 2020
;       cours:          INF2171
; ***********************************************************************
         LDA     table,i     ; pointe à l'alphabet
         STA     -2,s        
         SUBSP   2,i         ; #alphabet
         CALL    affiche     ; #retour
         STOP                
;
;IN:  SP+0=adresse de la table des caractères de l'alphabet
;
;OUT: ne retourne rien au programme principal
;
position:.EQUATE 0           ;#2d
sauveX:  .EQUATE 2           ;#2h
retour:  .EQUATE 4           ;#2h
alphabet:.EQUATE 6           ;#2h
;
affiche: SUBSP   4,i         ; #sauveX #position
         STX     sauveX,s    ; conserve la valeur du registre X
         STRO    demande,d   
         DECI    position,s  ; quel caractère ?
         LDX     position,s  
         SUBX    1,i         ; ajustement du premier caractère
         STRO    caractèr,d  
         CHARO   alphabet,sxf; affiche le caractère à la position demandée dans l'alphabet
         LDX     retour,s    ; place l'adresse de retour au bas de la pile
         STX     alphabet,s  
         LDX     sauveX,s    ; restaure le registre X original
         ADDSP   6,i         ; #retour #sauveX #position
         RET0                
;
table:   .ASCII  "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
demande: .ASCII  "Veuillez entrer la position numérique du caractère"
         .ASCII  "\ndans l'alphabet: \x00"
caractèr:.ASCII  "\nCe caractère est: \x00"
         .END