;Programme qui lit des données, les place dans un vecteur et les
;affiche une par ligne, précédées de leur indice. Les variables du
;programme sont placées sur la pile. Ph. Gabrini Mars 2006 (page 113)
;
TAILLE:  .EQUATE 12          ;taille du vecteur en entiers
vecteur: .EQUATE 2           ;tableau
index:   .EQUATE 0           ;variable
;
LitVec:  SUBSP   26,i        ;espace index et tableau
         LDX     0,i         ;int main() {
         STX     index,s     ;
Boucle1: CPX     TAILLE,i    ; for(i = 0; i < TAILLE; i++){
         BRGE    FinBouc1    ;
         ASLX                ; (entier = 2 octets)
         DECI    vecteur,sx  ; cin >> vector[i];
         LDX     index,s     ;
         ADDX    1,i         ;
         STX     index,s     ;
         BR      Boucle1     ; }
FinBouc1:LDX     TAILLE,i    ; for(i = TAILLE-1; i >= 0; i--){
         SUBX    1,i         ;
         STX     index,s     ;
         CHARO   '\n',i      ; cout << endl;
Boucle2: CPX     0,i         ;
         BRLT    FinBouc2    ;
         DECO    index,s     ; cout << index;
         CHARO   ' ',i       ; << ' '
         ASLX                ; (entier = 2 octets)
         DECO    vecteur,sx  ; << vector[i]
         CHARO   '\n',i      ; << endl;
         LDX     index,s     ;
         SUBX    1,i         ;
         STX     index,s     ;
         BR      Boucle2     ; }
FinBouc2:ADDSP   26,i        ; nettoyer pile
         STOP                ; return 0;}
         .END